Back to Gold Quest 6 GitHub page
Using font by Style
1 IFPEEK(792)=71THENPOKE792,193:REM VERSION 1.2 EN 29.05.-1
10 FORII=1TO18:READA:NEXT:DATA11,,3,4,2,2,64,,2,9,2,10,26,,1,4,6,8:REM SID DATA, DISTREMOVE
15 SI=54272:GOSUB9100:GOSUB9300:GOTO30

20 TI$="000000":FORZE=-1TO.:ZE=(TI<TW):NEXT:RETURN

25 O=INT(PM*100)
26 Z$=STR$(O):Z$=RIGHT$(Z$,LEN(Z$)-1):Z$=RIGHT$("00"+Z$,3)
27 O$=LEFT$(Z$,1)+"."+RIGHT$(Z$,2):RETURN

30 SC=1065:CO=55296:GOSUB9060:PRINTCHR$(8)"":POKE53280,0:POKE53281,0:L=100:LV=1:PM=1:G=1:W%=1:UT=6
32 REM RESET - PUNKTE, INV, DRACHEN, ITEMS, FULGI, QUESTS, HAENDLERZAEHLER
34 PU=.:I%=.:D%=.:AE=.:CF=.:WD=.:SW=.:JG=.:TS=.:HG=.:S%=.:FB=.:NQ=.:VQ=.:VO%=.:L1=.:VH%=.:H%=.
35 REM 12 MISSIONS - DRAGON PAL, ZOMBIE HUNTER, GAMBLER, FAIRY SWATTER, LITTLE COWARD
36 REM BEER DRINKER, STONE SOBER, PIGGY BANK, PARTY POOPER, GOURMET, ABSTAINER, HOLY SAINT
37 GA%=.:DF%=.:ZK%=.:ZO%=.:FK%=.:FG%=.:OS%=.:GL%=.:NU%=.:AB%=.:ES%=.:GT%=.:HE%=.
38 Q$="":FORII=1TO28:W(II,2)=.:NEXT:REM WAFFEN/ITEMS/ALK
50 GOSUB9000:X=16:GOSUB8198
54 SYSQ,1,17,"WHAT IS THY NAME? ";:A%=1:GOSUB800
61 IFG$=""THENG$="NOBODY":PRINTG$;
62 N$=G$:PRINT:IFN$="CHEATOR"THENPRINT" CHOOSE THE START DEPTH:";:V=2:H=15:GOSUB700:LV=A%
63 A$=" ADVENTURER":B$=" SCRIMPER":C$=" DEADBEAT":F$=" WARRIOR"
64 X=16:GOSUB8198:SYSQ,0,16,"CHOOSE YOUR DWARF:":PRINT""
65 SYSQ,0,18," CHARACTER  BOOZYGOLD WEAPON  BACKPACK "
66 SYSQ,13,19,"2.5  3  SPEAR   IMP ALE ":SYSQ,13,20,"0.5  9  DAGGER  GEMS"
67 SYSQ,13,21,"3.0  0  DAGGER  ORC BEER":SYSQ,13,22,"1.5  2  SWORD   SWATTER"
68 PRINT""A$CHR$(13)B$CHR$(13)C$CHR$(13)F$;
69 V=1:H=4:GOSUB700:IFA%=1THENG=3:PM=2.5:W%=2:W(22,2)=1:I%=1
70 IFA%=2THENG=9:PM=0.5:W(18,2)=1:I%=1:A$=B$
71 IFA%=3THENG=0:PM=3:W(24,2)=1:I%=1:A$=C$
72 IFA%=4THENG=2:PM=1.5:W%=3:W(17,2)=1:I%=1:A$=F$
73 REM G$="ENDE!":E$="":LV=9:PU=43210:G=1234:NQ=2:VQ=2:D%=7:S%=1:GOTO5900
74 REM LV=6:L1=6:VQ=1:VO%=2:REM ZWEITE QUEST LETZTER ORK VO%=ORKCOUNT
75 REM VO% =0 BESTANDEN, =-1 FRAU TOT, >0 NICHT GESUCHT
76 REM JG=2:LV=6:FB=1:L1=.:REM START 2. QUEST
77 REM LV=4:NQ=1:Q$="123456": REM 1. QUEST DONE
78 X=16:GOSUB8198:SYSQ,0,16," CONTROLS ":PRINT"     MOVE: JOYSTICK PORT 2 / WASD"
79 PRINT" BACKPACK: FIRE BUTTON / RETURN / I":PRINT"  GIVE UP: F1"
80 PRINTN$", THE"A$"!":A$="":GOSUB7800:TW=180:GOSUB20:POKE198,.
100 PRINT"":KA=0:U=0:Z=0:GM%=LV*20+60:GOSUB9250:GOSUB460:GOSUB200:IFD%>.THENGOSUB550
101 IFJG=-1THENJG=.
110 SYSQ,PX%+1,PY%+1,""C$(PR):GOSUB220:GOSUB500
111 IFDF%=2THENA$="DRAGON PAL":DF%=3:GOSUB197
112 IFZK%=12THENA$="ZOMBIE HUNTER":ZK%=13:GOSUB197
113 IFZO%=5THENA$="GAMBLER":ZO%=6:GOSUB197:REM AT-RISK
114 IFFK%=3THENA$="FAIRY SWATTER":FK%=4:GOSUB197
115 IFFG%=10THENA$="LITTLE COWARD":FG%=11:GOSUB197
116 IFOS%=10THENA$="BEER DRINKER":OS%=11:GOSUB197
117 IFHE%=2THENA$="HOLY SAINT":HE%=3:GOSUB197
118 IFNU%=.ANDPM<0.01THENA$="STONE SOBER":NU%=1:GOSUB197
119 IFGL%=.ANDG>249THENA$="PIGGY BANK":GL%=1:GOSUB197
120 IFES%=2THENA$="PARTY POOPER":ES%=3:GOSUB197
122 IFGT%=4THENA$="GOURMET":GT%=5:GOSUB197
124 REM ABSTAINER AB% 7200
130 GOSUB2000:IFPM<2THENL=L-1
132 IFG>GM%THENL=L-1
134 IFL<.THENL=.
136 PM=PM-.01:IFPM<.THENPM=.
138 IFE$=""THENG$="YOU REALLY GAVE UP!":A%=-1:GOTO7000
140 IFE$="+"THEN7200
142 IFL<1THENG$="YOU DIED MISERABLY! 0% HEALTH":A%=-1:GOTO7000
144 IFPM>3.51THENIFSW=.THENG$="YOU DIED HAPPILY! OVER 3.5 BOOZY":A%=-1:GOTO7000
150 N%=INT(RND(.)*3)*LV:IFLV<3THENN%=0
155 A%=K%(PX%,PY%)-2:IFA%<.THEN110
160 IFA%>13THEN195:REM >12
165 IFA%=.THEN7200:REM EXIT DOOR
170 GOSUB225
175 ONA%GOSUB4200,4000,5000,4100,5100,5200,5300,5400,5500,5600,5700,5800,6200
185 PU=PU+5:IFU=1THENLV=LV+1:GOSUB7805:GOTO100:REM FALLTUER
188 IFU=2THENPX%=XF:PY%=YF:U=.:GOSUB570:REM FLUCHT
189 IFU=3THEN5880:REM FULGORE KAMPF
190 GOTO110

195 A%=A%-13:SYSQ,1,21,"ON THE WALL YOU SEE RUNE"A%" "MID$(Q$,A%,1)"":REM -12
196 PRINT" REMEMBER IT WELL!";:K%(PX%,PY%)=1:GOSUB700:GOSUB570:GOTO110

197 SYSQ,1,20,"MISSION "A$" ACCOMPLISHED!":GA%=GA%+1
198 SYSQ,0,21,GA%"OF 12 DONE";:D=10:GOSUB750:GOSUB570:RETURN

200 SYSQ,23,0,"":FORII=1TO10STEP2:SYSQ,23,II,"            "
205 SYSQ,23,II+1,"            ":NEXT:SYSQ,23,11,""
210 SYSQ,0,18,"";
215 SYSQ,0,19," GOLD QUEST 6           DEPTH";:PRINT""LV""LEFT$("         ",11-LEN(STR$(LV))):RETURN

220 GOSUB225:POKE780,7:GOSUB9200:GOSUB300:GOSUB9250:RETURN

225 FORII=.TO12:M%(II)=.:NEXT
226 V=.:N=.:A1%=1:A2%=2:A3%=3:IFPR=0THEN230
227 IFPR=1THEN250
228 A1%=-1:A2%=-2:A3%=-3:IFPR=3THENGOTO250
230 IFK%(PX%-A1%ANDDX%,PY%-A3%ANDDY%)=.THENM%(0)=1
231 IFK%(PX%+A1%ANDDX%,PY%-A3%ANDDY%)=.THENM%(1)=1
232 K%=K%(PX%,PY%-A3%ANDDY%):IFK%=.THENM%(2)=1:N=1
233 IFK%=2THENM%(2)=2
234 IFK%(PX%-A1%ANDDX%,PY%-A2%ANDDY%)=.THENM%(3)=1
235 IFK%(PX%+A1%ANDDX%,PY%-A2%ANDDY%)=.THENM%(4)=1
236 K%=K%(PX%,PY%-A2%ANDDY%):IFK%=.THENM%(5)=1:N=2
237 IFK%=2THENM%(5)=2
238 IFK%>1ANDK%<16THENM%(12)=1:REM <15
239 IFK%(PX%-A1%ANDDX%,PY%-A1%ANDDY%)=.THENM%(6)=1
240 IFK%(PX%+A1%ANDDX%,PY%-A1%ANDDY%)=.THENM%(7)=1
241 K%=K%(PX%,PY%-A1%ANDDY%):IFK%=.THENM%(8)=1:N=3:GOTO245
242 IFK%=2THENM%(8)=2
243 IFK%>2ANDK%<16THENM%(11)=1:REM <15
244 K=SC+PX%+(40*(PY%-A1%ANDDY%)):IFPEEK(K)=160THENPOKEK,164
245 K%=K%(PX%-A1%ANDDX%,PY%):IFK%=.ORK%=2THENM%(9)=1:GOTO247
246 K=SC+(PX%-A1%ANDDX%)+PY%*40:IFPEEK(K)=160THENPOKEK,164
247 K%=K%(PX%+A1%ANDDX%,PY%):IFK%=.ORK%=2THENM%(10)=1:RETURN
248 K=SC+(PX%+A1%ANDDX%)+PY%*40:IFPEEK(K)=160THENPOKEK,164
249 RETURN

250 IFK%(PX%+A3%ANDDX%,PY%-A1%ANDDY%)=.THENM%(0)=1
251 IFK%(PX%+A3%ANDDX%,PY%+A1%ANDDY%)=.THENM%(1)=1
252 K%=K%(PX%+A3%ANDDX%,PY%):IFK%=.THENM%(2)=1:N=1
253 IFK%=2THENM%(2)=2
254 IFK%(PX%+A2%ANDDX%,PY%-A1%ANDDY%)=.THENM%(3)=1
255 IFK%(PX%+A2%ANDDX%,PY%+A1%ANDDY%)=.THENM%(4)=1
256 K%=K%(PX%+A2%ANDDX%,PY%):IFK%=.THENM%(5)=1:N=2
257 IFK%=2THENM%(5)=2
258 IFK%>1ANDK%<16THENM%(12)=1:REM <15
259 IFK%(PX%+A1%ANDDX%,PY%-A1%ANDDY%)=.THENM%(6)=1
260 IFK%(PX%+A1%ANDDX%,PY%+A1%ANDDY%)=.THENM%(7)=1
261 K%=K%(PX%+A1%ANDDX%,PY%):IFK%=.THENM%(8)=1:N=3:GOTO265
262 IFK%=2THENM%(8)=2
263 IFK%>2ANDK%<16THENM%(11)=1:REM <15
264 K=SC+(PX%+A1%ANDDX%)+PY%*40:IFPEEK(K)=160THENPOKEK,164
265 K%=K%(PX%,PY%-A1%ANDDY%):IFK%=.ORK%=2THENM%(9)=1:GOTO267
266 K=SC+PX%+(PY%-A1%ANDDY%)*40:IFPEEK(K)=160THENPOKEK,164
267 K%=K%(PX%,PY%+A1%ANDDY%):IFK%=.ORK%=2THENM%(10)=1:RETURN
268 K=SC+PX%+(PY%+A1%ANDDY%)*40:IFPEEK(K)=160THENPOKEK,164
270 RETURN

300 A$="":B%=.:C%=.:IFM%(8)=.THEN305
301 M%(5)=.:M%(2)=.:M%(12)=.:IFM%(6)>.ORM%(9)>.THENM%(0)=.:M%(3)=.
302 IFM%(7)>.ORM%(10)>.THENM%(1)=.:M%(4)=.
303 IFM%(9)>.THENM%(6)=.
304 IFM%(10)>.THENM%(7)=.
305 IFM%(5)=.THEN308
306 M%(2)=.:M%(12)=.:IFM%(6)>.THENM%(0)=.
307 IFM%(7)>.THENM%(1)=.
308 IFM%(3)>.THENM%(0)=.
309 IFM%(4)>.THENM%(1)=.
310 SYSQ,24,1,"";:FORII=1TO10:PRINT"            ";:NEXT
311 IFM%(8)=1THEN370
312 IFM%(5)=1THEN340
315 IFM%(3)=1THEN320
316 IFM%(0)=1THENSYSQ,27,4,"";
320 IFM%(4)=1THEN330
322 IFM%(1)=1THENSYSQ,32,5,"";
330 IFM%(2)=.ORN>1THEN334
332 SYSQ,28,4,"  ";
334 IFN=3THEN370
336 IFM%(2)=2THENIFN<2THENSYSQ,28,4,"";
340 IFM%(6)=1THEN344
342 IFM%(3)=1THENSYSQ,25,4," ";
344 IFM%(3)=1ANDM%(5)=.THENSYSQ,27,4,"";
350 IFM%(7)=1THEN354
352 IFM%(4)=1THENSYSQ,33,4," ";
354 IFM%(4)=1ANDM%(5)=.THENSYSQ,32,4,"";
360 IFM%(5)=.ORN>2THEN364
362 SYSQ,27,4,"    ";
364 IFM%(5)=2ANDN<3THENSYSQ,27,4,"&& && &&";
370 IFM%(9)=.THENSYSQ,24,2,"";
374 IFM%(6)=1ANDM%(8)=.THENSYSQ,25,2,"    ";
380 IFM%(10)=.THENSYSQ,35,2,"";
384 IFM%(7)=1ANDM%(8)=.THENSYSQ,34,2,"    ";
386 IFM%(12)=.THEN390
388 IFM%(5)<>2THENIFN<3THENSYSQ,29,6,"?";
390 IFM%(8)<>1THEN400
392 SYSQ,25,2,"";
394 FORII=3TO7:PRINT"        ";:NEXT:PRINT"";
400 IFM%(9)=1THENSYSQ,24,1,"";
402 IFM%(10)=1THENSYSQ,35,1,"";
404 IFM%(11)=1THENSYSQ,28,7,".";
406 IFM%(8)<>2THENRETURN
410 SYSQ,25,2,"";
412 FORII=3TO7:PRINT"  ";:NEXT
414 PRINT"";
420 RETURN

460 PRINT" ";:FORII=1TOGX/4:PRINT"";:NEXT:PRINT
462 FORII=1TOGY:PRINT""CHR$(180+RND(.)*2);
463 PRINTLEFT$("                ",GX)CHR$(170+INT(RND(.)*2)*12):NEXT
464 PRINT"";:FORII=1TOGX/4:PRINT"";:NEXT:PRINT"":PRINT"":RETURN

470 KA=1
471 FORII=0TOGY-1:SYSQ,1,II+1,"";:FORJJ=0TOGX-1:PRINTK$(K%(JJ,II));:NEXT:NEXT
472 RETURN

500 SYSQ,20,0,"NWES";:PRINTMID$("NESW",PR+PR+1,2)
501 IFI%>3THENPRINT"";
502 SYSQ,24,16,"BACKPACK"I%"/4":IFL<.THENL=.
505 IFAE=1THENPRINT"";:IFE$="W"THENL=L+1
506 IFL>100THENL=100
510 SYSQ,24,12,"HEALTH"L"%  "
520 IFSW=.THENIFPM>2THENPRINT"";
521 IFSW>.THENPM=3.5:PRINT"";
522 SYSQ,24,13,"BOOZY ";:GOSUB25:PRINTO$;
530 IFG>GM%THENSYSQ,24,14,"GOLD"G"   ";:GOTO533
531 SYSQ,24,14,"GOLD"G"   ";
533 SYSQ,24,15,W$(W%):SYSQ,24,17,"POINTS"PU:IFWD=1THENSYSQ,20,15,"2X";
540 IFHG=2THENSYSQ,20,16,"HG";
541 IFCF=1THENSYSQ,20,12,"CF";
542 IFJG>.THENSYSQ,20,13,"JG";:REM IFJG=1
543 IFTS=1THENSYSQ,20,14,"TS";
545 RETURN

550 SYSQ,19,4,"DRAGONS";
555 FORII=1TOD%:SYSQ,20,3+II,MID$("",II,1)">>":NEXT:RETURN

570 FORII=20TO24:SYSQ,0,II,"                                       ";:NEXT
571 RETURN

670 BX%=RND(.)*GX:BY%=RND(.)*GY:IF(BX%AND1)=1THENIF(BY%AND1)=1THEN670
671 IFK%(BX%,BY%)>1THEN670
673 IFBX%=PX%THENIFBY%=PY%THEN670
676 K%(BX%,BY%)=KK%:RETURN

680 IFK%=14THENK%(PX%,PY%)=1:RETURN
681 BX%=RND(.)*GX:BY%=RND(.)*GY
682 IFK%(BX%,BY%)<>1OR(BX%=PX%ANDBY%=PY%)OR(BX%=XFANDBY%=YF)THEN681
683 K%(PX%,PY%)=1:SYSQ,PX%+1,PY%+1," ":K%(BX%,BY%)=K%:IFKA=.THENRETURN
685 SYSQ,BX%+1,BY%+1,K$(K%):RETURN

700 SP=PEEK(211):ZE=PEEK(214):A%=1:POKE198,.:J=-1
705 IFPEEK(56320)AND127<>127THEN705
710 IFV=.THENSYSQ,(A%-1)*B%+C%,ZE,">";
711 IFV=1THENSYSQ,0,ZE-H+A%,">";
712 IFV=2THENSYSQ,SP,ZE,A%" ";
713 IFTI<9AND(PEEK(56320)AND127)=JTHEN713
715 J=PEEK(56320)AND127:GETT$:IFJ=127THENIFT$=""THENT=.:GOTO715
716 TI$="000000"
717 IFT$="W"ORT$="A"ORT$="J"ORT$=""ORT$=""THENJ=123
718 IFT$="S"ORT$="D"ORT$="N"ORT$=""ORT$=""THENJ=119
720 IFV=.THENSYSQ,(A%-1)*B%+C%,ZE," ";
722 IFV=1THENSYSQ,0,ZE-H+A%," ";
724 IFJ=126ORJ=123THENIFA%>1THENA%=A%-1
726 IFJ=125ORJ=119THENIFA%<HTHENA%=A%+1
728 IF(J=111ORT$=CHR$(13)ORV=3)THENIFT=.THEN740
730 IFVAL(T$)>=1THENIFVAL(T$)<=HTHENA%=VAL(T$)
732 GOTO710

740 T=1:V=.:H=1:B%=.:C%=.:D=.:IFZE<24THENSYSQ,SP,ZE,""
742 RETURN

750 SYSQ,0,PEEK(214),">";:TI$="000000":POKE198,.:IFD=.THEND=2
751 IFV=3THENPRINT" ";:SYSQ,9,24," STRIKE ANY KEY ";:D=6000
752 J=PEEK(56320)AND127:GETT$:IFJ=127THENT=.
754 IF(J=111ANDT=.)ORT$<>""ORINT(TI/60)>DTHENT=1:D=.:POKE198,.:RETURN
756 GOTO752

800 G$="":C$="$":IFA%=1ANDN$<>""THENG$=N$:A%=42
802 PRINT""G$C$;
810 J=PEEK(56320)AND127:GETE$:IFJ=127ANDE$=""THEN810
811 IFJ<>127THEN830
812 PRINTC$;:E=ASC(E$):IF(E<45ORE>57)AND(E<65ORE>93)ANDE<>13ANDE<>20ANDE<>32THEN810
814 A%=LEN(G$):IFE=13THENPRINT" ";:RETURN
816 IFE=20ANDA%>.THENG$=LEFT$(G$,A%-1):PRINT""C$" ";:GOTO810
818 IFA%<11ANDE<>20THENG$=G$+E$:PRINTE$C$;
820 GOTO810

830 IFJ<>119ANDJ<>123THEN810
831 E=1:IFLEN(G$)=11ORJ=123ORA%=42THENE=41
833 A$=MID$("ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.- ",E,1):PRINT""A$"";
835 TW=9:GOSUB20
840 J=PEEK(56320)AND127:GETE$:IFJ=127ANDE$=""THEN840
841 IFE$<>""THEN812
842 IFJ=111THEN850
844 IFJ=119THENE=E+1:IFE>41THENE=1
846 IFJ=123THENE=E-1:IFE<1THENE=41
848 GOTO833

850 TW=10:GOSUB20:IFE=40THENE$=CHR$(20):GOTO812
852 IFE=41THENE=13:GOTO814
854 E$=A$:GOTO812

900 P=0:FORII=4TO0STEP-1:IFPU>P(II)THENP=II+1:NEXT
902 GOSUB930:E$=R$:GOSUB960
904 IFP=0ORN$="CHEATOR"THEN950
908 IFP=4THEN920
910 FORII=4TOPSTEP-1:N$(II)=N$(II-1):P(II)=P(II-1):R$(II)=R$(II-1):NEXT
920 N$(P-1)=N$:P(P-1)=PU:R$(P-1)=R$
922 PRINT""N$" BECOMES A "E$" AND"
924 PRINT"ENTERS THE HALL OF THE FAMOUS DWARVES!":GOSUB9320:RETURN

930 IFPU<500THENR$="BEER NURSLING"
931 IFPU>499THENR$="TUNNEL DIGGER"
932 IFPU>999THENR$="STONE MASON"
933 IFPU>1499THENR$="SPELUNKER"
936 IFPU>2999THENR$="GOLD DIGGER"
937 IFPU>4999THENR$="MASTER SMITH"
938 IFPU>7499THENR$="DWARF ELDER"
939 IFPU>9999THENR$="GREYBEARD"
940 IFPU>13999THENR$="RUNE PRIEST"
941 IFPU>16999THENR$="DWARF KING"
942 RETURN

950 PRINT""N$" SCORED"PU"POINTS AND":PRINT"BECOMES A "E$" BUT SADLY WILL"
952 PRINT"NOT BE ADMITTED TO THE HALL OF FAME.":RETURN

960 S$=""+RIGHT$(STR$(LV),2):Q$=" ":IFNQ=2THENQ$=""
964 S$=S$+Q$:Q$="":IFVQ=2THENQ$=""
965 S$=S$+Q$:Q$="":IFD%>.THEND%=D%-1:GOSUB7897:Q$=K$(13)
966 S$=S$+Q$:Q$="":IFS%=1THENQ$="@"
968 R$=S$+Q$+" "+R$:RETURN

1000 GX=16:GY=16:IFLV<6THENGX=8:GY=16
1015 IFLV<5THENGX=16:GY=8
1017 IFLV<4THENGX=16:GY=4
1020 IFLV<3THENGX=8:GY=8
1021 IFLV<2THENGX=8:GY=4
1022 M%=.:FX%=.:FY%=.:FZ%=-1:DX%=GX-1:DY%=GY-1
1025 FORII=.TODY%:FORJJ=.TODX%:K%(JJ,II)=.:NEXT:NEXT
1030 FX%=INT(RND(.)*GX/2)*2:FY%=INT(RND(.)*GY/2)*2:K%(FX%,FY%)=1:PX%=FX%:PY%=FY%
1100 FZ%=FZ%+1:FS%(FZ%,.)=FX%:FS%(FZ%,1)=FY%:IFFZ%>M%THENM%=FZ%:EX%=FX%:EY%=FY%
1110 R%=.:IFK%(FX%,FY%-2ANDDY%)=.THENR%(R%)=.:R%=R%+1
1120 IFK%(FX%+2ANDDX%,FY%)=.THENR%(R%)=1:R%=R%+1
1130 IFK%(FX%,FY%+2ANDDY%)=.THENR%(R%)=2:R%=R%+1
1140 IFK%(FX%-2ANDDX%,FY%)=.THENR%(R%)=3:R%=R%+1
1145 IFR%=.THEN1250
1150 A%=RND(.)*R%:IFFZ%=.THENPR=A%
1160 IFR%(A%)=.THENK%(FX%,FY%-1ANDDY%)=1:FY%=FY%-2ANDDY%:K%(FX%,FY%)=1
1170 IFR%(A%)=1THENK%(FX%+1ANDDX%,FY%)=1:FX%=FX%+2ANDDX%:K%(FX%,FY%)=1
1180 IFR%(A%)=2THENK%(FX%,FY%+1ANDDY%)=1:FY%=FY%+2ANDDY%:K%(FX%,FY%)=1
1190 IFR%(A%)=3THENK%(FX%-1ANDDX%,FY%)=1:FX%=FX%-2ANDDX%:K%(FX%,FY%)=1
1200 GOTO1100

1250 IFFZ%=.THENK%(EX%,EY%)=2:RETURN
1270 FZ%=FZ%-1:FX%=FS%(FZ%,.):FY%=FS%(FZ%,1):GOTO1110

1600 GOSUB570:M=INT(KW/3):MB=INT((RND(1)*M)+1.5-INT(M/2)):F=.
1601 S=INT(KW-PM*10-MB):IFS<1THENS=INT(RND(1)*LV)
1602 KW%=KW/2+LV
1603 IF(JG>.ANDK%=14)THEN1606
1604 IFJG>.THENA$="":GOSUB1673:GOTO1660
1606 IFHG=3THENMB=INT(RND(1)*25)+25:HG=0:SYSQ,20,16,"  "
1607 GOSUB9900
1609 IFWD=1THENPK%=INT(PM*5+.5)+MB+2*W(W%,0):GOTO1611
1610 PK%=INT(PM*5+.5)+MB+W(W%,0):IFPK%<1THENPK%=1
1611 GOSUB9690:A$=" IN BATTLE!                  ":IFKW%<=PK%THEN1613
1612 SYSQ,1,20,"YOU ARE DEFEATED"A$:GOSUB680:GOTO1615

1613 SYSQ,1,20,"YOU ARE VICTORIOUS"A$:F=1:GOSUB1670
1614 SYSQ,14,21,"GOLD +"BB%" POINTS +"KW
1615 SYSQ,1,21,"HEALTH -"ABS(S)"%"
1620 SYSQ,1,23,K$""TAB(11);:I=KW%:GOSUB9720
1622 SYSQ,1,22,"STRENGTH  ";:I=PK%:GOSUB9720:SYSQ,1,20,"";
1625 IFF>.THENPU=PU+KW:G=G+BB%
1627 IFMB>25THENSYSQ,37,22,"HG"
1628 IFK%=13THENIFF=1THEND%=D%+1
1629 IFK%=14THENIFF=1THENIFFB>1THENS%=1
1633 K%(PX%,PY%)=1:L=L-S:A$=""
1634 D=7:GOSUB750:GOSUB570:IFD%>.THENGOSUB550
1635 IFK%=14THENIFFB<2ORF=0THEN1690
1639 IFF=.THENSYSQ,1,20,K$" MOVES ON";:GOSUB750:RETURN
1640 Z=INT(RND(1)*(16+W%+LV)-(KW/10)):B%=INT(RND(1)*3):A%=0
1641 A$="DEAD ":IFK$="ZOMBIE"THENA$="CHOPPED ":ZK%=ZK%+1
1642 SYSQ,1,20,"YOU SEARCH THE "A$K$;:REM IFK%=13THENPRINT"N"
1643 IFI%=4THEN1650
1644 IFZ=.THENIFW(13,2)=0THENB$=W$(13):W(13,2)=1:I%=I%+1:A%=1
1646 IFZ=1ORZ=2THENIFW(22+B%,2)=0THENB$=W$(22+B%):W(22+B%,2)=1:I%=I%+1:A%=1
1648 IFZ=3ORZ=4THENIFW(17+B%,2)=0THENB$=W$(17+B%):W(17+B%,2)=1:I%=I%+1:A%=1
1650 IFZ=5ORZ=6THENIFW%<12THENW%=W%+1:B$=W$(W%):A%=1
1652 IFZ=7ORZ=8THENB$=""+STR$(B%+LV)+" GOLD":G=G+B%+LV:A%=1:POKE780,6:TW=60:GOSUB9270
1654 SYSQ,1,21,"AND FIND ";:IFA%=0THENPRINT"NOTHING";:GOSUB750:RETURN
1655 PRINTB$"";:GOSUB750:RETURN

1660 JG=JG-1:SYSQ,1,20,"YOU GIVE A GLASS MARBLE "JG"( LEFT)":F=2:IFK%=13THEND%=D%+1:DF%=DF%+1:GOSUB550
1661 SYSQ,1,21,K$" TRADES"BB%"GOLD AND"KW"POINTS":PU=PU+KW:G=G+BB%
1662 SYSQ,1,23,K$" IS NOW YOUR ALLY";:D=6:GOSUB750:K%(PX%,PY%)=1:IFVO%>1THENVO%=VO%-1
1663 IFJG=.THENSYSQ,20,13,"  ":IFK%=9ORK%=10THENJG=-1
1665 RETURN

1670 IFK%=14THENIFFB<2THENRETURN
1671 IFK%=14THENIFFB=2THENPOKE780,5:TW=60:GOSUB9270
1672 A$="X"
1673 A%=29:B%=2:C%=1:IFK%=11THENB%=4
1674 IFK%=13THENA%=28:B%=4:C%=2
1676 IFK%=14THENA%=28
1678 SYSQ,A%,B%,""A$SPC(C%)A$:C%=0:A$="":RETURN

1690 IFL<1THENRETURN
1691 IFFB=0THENSYSQ,1,20,"THIS FIGHT AIN'T OVER!"
1692 IFFB=1THENSYSQ,1,20,"I SHALL CRUSH YOU NEXT TIME!"
1693 IFFB=2THENSYSQ,1,20,"YOU CAN'T KILL ME, UNWORTHY IMP!"
1694 IFF=1THENFB=FB+1:IFFB>2THENFB=2
1696 SYSQ,1,21,K$" MOVES AWAY TO DEPTH"LV+1;
1697 IFF=1THENSYSQ,1,23,"YOU ONLY WEAKENED THE SHAMAN":GOTO1699
1698 SYSQ,1,23,"YOU DID NOT DEFEAT THE SHAMAN"
1699 SYSQ,1,24,"AND HAVE TO FACE HIM AGAIN";:D=9:GOSUB750:RETURN

1700 GOSUB570:IFI%=0THENSYSQ,1,21,"ABSOLUTELY NOTHING IN HERE";:GOTO1770
1710 SYSQ,1,20,"CLOSE BACKPACK":Z=1
1715 FORII=13TO25:IFW(II,2)=1THENSYSQ,1,20+Z,W$(II);:I(Z)=II:Z=Z+1
1720 NEXT:V=1:H=Z:GOSUB700:A%=A%-1:IFA%=.THENGOSUB570:RETURN
1740 GOSUB570:C$="":IFI(A%)=13THENGOSUB470
1744 IFI(A%)=14THENL=101:AE=1:C%=1
1746 IFI(A%)=15THENWD=1
1748 IFI(A%)=16THENSW=1
1750 IFI(A%)=17THENCF=1:C$="CF"
1752 IFI(A%)=18THENJG=JG+3:C$="JG"
1754 IFI(A%)=19THENTS=1:C$="TS"
1756 IFI(A%)=20THENHG=2:C$="HG"
1758 IFI(A%)>20THENL=L+W(I(A%),0):PM=PM+W(I(A%),1):C%=1:IFI(A%)=24ORI(A%)=25THENOS%=OS%+1
1760 IFC%=0THENSYSQ,1,21,"YOU USE "W$(I(A%))" "C$"";
1762 IFC%=1THENSYSQ,1,21,"YOU DRINK "W$(I(A%));:C%=0:AB%=1
1764 W(I(A%),2)=0:I%=I%-1
1770 GOSUB750:GOSUB570:RETURN

2000 SYSQ,0,21,L$
2001 J=PEEK(56320)AND127:IFJ<>127THEN2001
2002 GETE$:J=PEEK(56320)AND127:IFJ=127THENIFE$=""THEN2002
2003 IFJ=126ORE$="W"THENE$="W":GOTO2030
2004 IFJ=125ORE$="S"THENE$="S":GOTO2030
2005 AU%=.:IFJ=119ORE$="D"THENE$="D":GOTO2030
2006 IFJ=123ORE$="A"THENE$="A":GOTO2030
2007 IFJ=111ORE$="I"ORE$=CHR$(13)THENE$="I":GOSUB1700:RETURN
2008 IFE$=""THEN2100
2010 IFN$<>"CHEATOR"THEN2000
2012 IFE$=""THENE$="":S%=1:A%=1:GOTO5900:REM INSTANT WIN - EASTER EGG
2013 IFE$="G"THENG=G+20:RETURN:REM GOLD
2014 IFE$="M"THENGOSUB470:RETURN:REM MAP
2015 IFE$="+"THENRETURN:REM NEXT LV
2016 IFE$="!"THENL=100:PM=3.5:W%=12:AE=1:CF=1:SW=1:TS=1:WD=1:RETURN:REM GODMODE
2017 REM IFE$="&"THENIFI%<4THENGOSUB2300:RETURN:REM ITEM
2018 REM IFE$="$"THENL=100:AE=1:CF=1:SW=1:TS=1:WD=1:RETURN:REM MAX DOPING
2019 REM IFE$="0"THENSYSQ,0,22,"U"U"W%"W%" RQ"NQ;Q$:REM DEBUG
2020 REM IFE$="0"THENSYSQ,0,23,"JG"JG"VQ"VQ"VO%"VO%"L1"L1
2021 REM IFE$="0"THENSYSQ,0,24,"UT"UT"F"F"FB"FB"S%"S%"GM%"GM%;
2022 REM IFE$="0"THENSYSQ,0,22,"DF"DF%"ES"ES%"ZK"ZK%"ZO"ZO%"FK"FK%"FG"FG%"OS"OS%:SYSQ,0,23,"AB"AB%"AC"AC%"GL"GL%"NU"NU%"GA"GA%
2023 REM IFE$=""THENSYSQ,0,24,"FREE RAM"FRE(.)-65536*(FRE(.)<.);
2024 REM IFE$="%"THENPM=3.5:RETURN:REM PROMILLE MAX
2025 REM IFE$="."THENL=100:K%(PX%,PY%)=5:RETURN:REM FALLENTEST
2026 REM IFE$=","THENGOSUB4000:RETURN:REM TRANKTEST
2027 REM IFE$="#"THENGOSUB2200:RETURN:REM NPC TEST
2028 REM IFE$="*"THEND%=D%+1AND7:GOSUB550:REM DRACHE
2029 GOTO2000

2030 SYSQ,PX%+1,PY%+1," ":X=.:Y=.
2040 IFE$="D"THENPR=PR+1AND3:RETURN
2042 IFE$="A"THENPR=PR-1AND3:RETURN
2044 IFE$="W"THENA%=-1:B%=1
2046 IFE$="S"THENA%=1:B%=-1
2050 IFPR=3THENIFK%(PX%+A%ANDDX%,PY%)<>.THENX=A%:GOTO2080
2052 IFPR=1THENIFK%(PX%+B%ANDDX%,PY%)<>.THENX=B%:GOTO2080
2054 IFPR=.THENIFK%(PX%,PY%+A%ANDDY%)<>.THENY=A%:GOTO2080
2056 IFPR=2THENIFK%(PX%,PY%+B%ANDDY%)<>.THENY=B%:GOTO2080
2070 SYSQ,1,21,"OUCH!":POKESI+18,129:TW=15:GOSUB20:POKESI+18,128
2075 SYSQ,PX%+1,PY%+1,""C$(PR):L=L-1:IFL<1THEN130
2076 GOSUB500:AU%=AU%+1:IFAU%=3THEN2100
2077 GOTO2000

2080 PX%=PX%+XANDDX%:PY%=PY%+YANDDY%:SYSQ,PX%+1,PY%+1,""C$(PR):RETURN

2100 SYSQ,1,21,"DO YOU WANT TO GIVE UP?  NO  YES";:H=2:C%=25:B%=4:GOSUB700
2101 E$="":IFA%=1THEN2000
2102 RETURN

2200 REM SYSQ,0,20,"1HN 2KOB 3ORK 4WC 5FEE":SYSQ,0,21,"6DKR 7TRO/ZOM  8DRA 9FUL"
2205 REM GETE$:A%=VAL(E$):IFA%=.THEN2205
2207 REM GOSUB570:IFA%=8THENK%(PX%,PY%)=13
2220 REM ONA%GOSUB4200,5200,5300,5400,5100,6200,5600,5700,5800:GOSUB200:RETURN
2300 REM SYSQ,0,20,"1LZ 2AE 3PW 4SA 5CF 6JG 7TS 8HG"
2304 REM GETE$:A%=VAL(E$):IFA%=.THEN2304
2308 REM GOSUB570:W(12+A%,2)=1:I%=I%+1:RETURN
4000 GOSUB570:SYSQ,29,5,"":SYSQ,28,6," "
4010 SYSQ,28,7,"  ":SYSQ,28,8,"% ":SYSQ,28,9,"  "
4015 GOSUB9650:GOSUB570:I=INT(RND(1)*100)+1:SYSQ,1,21,"YOU FIND ";
4020 Z=21:IFI>29THENZ=22
4024 IFI>49THENZ=23
4026 IFI>80THENZ=24
4027 IFI>90THENZ=25
4028 PRINTW$(Z);:SYSQ,1,22,"TAKE ALONG OR  DRINK UP";:H=2:B%=15:GOSUB700
4032 IFA%=2THENPRINT" OH, THAT VELVETY AFTERTASTE!";:L=L+W(Z,0):PM=PM+W(Z,1):AB%=1:IFZ=24ORZ=25THENOS%=OS%+1
4035 IFA%=1THENIFI%>3THENPRINT" TOO MUCH BAGGAGE";:GOTO4040
4036 IFA%=1THENIFW(Z,2)=1THENPRINT" YOU HAVE THAT ALREADY";:GOTO4040
4038 IFA%=1THENPRINT" YOU PUT IT IN YOUR BACKPACK";:W(Z,2)=1:I%=I%+1
4040 K%(PX%,PY%)=1:GOSUB750:GOSUB570:RETURN

4100 I=INT(RND(1)*5)+1+LV:G=G+I:A%=.:IFI<11THENA%=1
4103 SYSQ,29,6," ";
4105 PRINT"":IFI<6THEN4120
4110 SYSQ,28,7+A%,"":SYSQ,26,8+A%,"":IFA%=.THENSYSQ,25,9,""
4120 POKE780,6:TW=60:GOSUB9270:GOSUB570
4130 SYSQ,1,21,"YOU FIND"I"GOLD";:GOSUB750:GOSUB570:K%(PX%,PY%)=1:RETURN

4200 GOSUB570:K$="CAMI":PU=PU-5
4201 IB=INT(RND(1)*2):IFIB=1THENK$="WENDOR":PS=.5:GOTO4280
4202 GOSUB9640:SYSQ,28,1,"  ";
4203 PRINT"      ";
4204 PRINT"      ";
4205 PRINT"  SALE *     *";
4206 PRINT"  ";
4210 GOSUB9640:SYSQ,1,20,"KEEP WALKING OR BROWSE "K$"'S WARES:"
4211 IFW%>11THENA(1)=20:GOTO4215
4212 A(1)=W%+1
4215 FORX=1TO3
4216 IFX>1THENZ=INT(RND(.)*7)+13:A(X)=Z
4217 IFX=2THENIFW(Z,2)=1THEN4216
4218 IFX=3THENIFZ=A(2)ORW(Z,2)=1THEN4216
4219 D=W(A(X),1)+LV+INT(PM):IFIB=1THEND=INT(D*PS)
4220 SYSQ,1,20+X,W$(A(X)):SYSQ,23,20+X,"GOLD"D;:NEXT:V=1:H=4:GOSUB700
4230 A$=" TROOPS ONWARDS":IFA%=1ANDH%=1THENSYSQ,0,18,L$:A$=" CLOSES HIS STORE"
4231 IFA%=1ANDH%=2THENSYSQ,0,18,L$:A$=": NOTHING YOU WANT?"
4232 IFA%=1THENGOSUB570:SYSQ,1,21,K$A$;:GOTO4260
4233 I=A%-1:K%=W(A(I),1)+LV+INT(PM):IFIB=1THENK%=INT(K%*PS)
4237 GOSUB570:IFI=1THENIFW%<12THEN4241
4238 IFI%>3THENSYSQ,1,21,"CAN'T CARRY ANY MORE STUFF";:GOTO4260
4241 IFK%>GTHENSYSQ,1,21,"BUMMER! NOT ENOUGH GOLD";:GOTO4260
4244 IFW(A(I),2)=1THENSYSQ,1,21,""W$(A(I))" ALREADY OWNED";:GOTO4260
4250 IFI=1THENG=G-K%:W%=A(1):IFA(1)=20THENW%=12:W(A(I),2)=1:I%=I%+1:HE%=HE%+1
4251 IFI>1THENG=G-K%:I%=I%+1:W(A(I),2)=1
4256 SYSQ,1,21,"YOU BUY "W$(A(I));:K%(PX%,PY%)=1:H%=0:GOSUB750:GOSUB570:RETURN

4260 GOSUB750:IFH%<1THENK%=3:GOSUB680
4265 H%=H%-1:GOSUB570:RETURN

4280 GOSUB9640:SYSQ,28,1,"   ";
4282 PRINT"  ,  ";
4284 PRINT"S ' ";
4286 PRINT"   AL   E ";
4288 PRINT"    ";:GOTO4210

4400 SYSQ,1,20,K$" ATTACKS YOU!"
4402 SYSQ,1,21,"FIGHT OR  RETREAT";
4403 REM IF JG=1THEN PRINT"   JG GEBEN";:B%=10:C%=4:H=3:GOSUB700:GOTO4406
4404 IFHG=2THENPRINT"   HG THROW";:B%=10:H=3:GOSUB700:GOTO4407
4405 B%=10:H=2:GOSUB700:RETURN

4406 REM IF A%=3THENJG=2:A%=1:RETURN
4407 IFA%=3THENHG=3:A%=1:RETURN
4408 RETURN

4410 S=INT(G/25+LV+RND(1)*(2*G/25+LV)):REM S=INT(RND(1)*G/5)+INT(RND(.)*2*LV)
4415 GOSUB9900:SYSQ,PX%+1,PY%+1," ":SYSQ,0,21,L$
4416 SYSQ,1,21,"YOU MAKE AN ESCAPE...";:D=3:IFS>0THENPRINT" HEALTH -"ABS(S)"%";
4418 IFG>50THENG=G-INT(G/100*(RND(1)*11+10)):PRINT:PRINT" YOU LOST GOLD ON THE RUN!";
4419 IFLV>4THENFG%=FG%+1
4420 XF=INT(RND(1)*GX):YF=INT(RND(1)*GY):IFK%(XF,YF)<>1OR(XF=PX%ANDYF=PY%)THEN4420
4425 L=L-S:K%(PX%,PY%)=1:U=2:RETURN

4900 SYSQ,28,8,"":GOSUB9630:GOSUB9660:K%(PX%,PY%)=1
4905 SYSQ,1,21,"THE TRAP CAN'T DO YOU ANY HARM! TS";:GOSUB750:RETURN

5000 GOSUB570:GOSUB9670:SYSQ,28,7,"      ":I=INT(RND(1)*90)+10
5001 IFTS=1THEN4900
5002 IFI>90THENI=6:IF(INT(LV/2)<>LV/2)ORLV=2THENI=5:GOTO5009
5003 IFI>78THENI=5
5004 IFI>60THENI=4
5005 IFI>30THENI=3
5006 IFI>20THENI=2
5007 IFI>9THENI=1
5008 REM IFE$="."THENI=6:REM FALLGRUBE TEST
5009 ONIGOSUB5020,5030,5040,5050,5060,5070
5010 GOSUB750:GOSUB570:K%(PX%,PY%)=1:RETURN

5020 SYSQ,27,8,";;;;;;;;;;"
5023 SYSQ,1,21,"YOU ACCIDENTALLY STEP ON LAVA -20%";:L=L-20:GOSUB9670:RETURN

5030 SYSQ,27,8,",;,;;,;,;,"
5033 SYSQ,1,21,"YOU VALIANTLY WALK THROUGH THORNS -12%";:L=L-12:GOSUB9670:RETURN

5040 SYSQ,27,8,"":SYSQ,26,9,""
5043 SYSQ,1,21,"YOU TRIP OVER SOME NASTY RUBBLE -8%";:L=L-8:GOSUB9670:RETURN

5050 SYSQ,26,1,"       "
5053 SYSQ,1,21,"YOU TRIGGER A HIDDEN ARROW TRAP -15%";:L=L-15
5054 FORU=.TO3:GOSUB9630:NEXT:RETURN

5060 SYSQ,27,8,"><><"
5065 FORU=.TO5:GOSUB9660:NEXT:S=9:SYSQ,PX%+1,PY%+1," ":GOSUB4420
5068 SYSQ,1,21,"YOU RUN CONFUSED INTO A TELEPORTAL -9%";:RETURN

5070 SYSQ,27,8,"     ":U=1:L=L-10:IFVQ=1THENL1=L1+1
5073 SYSQ,1,21,"YOU PLUMP DOWN TO DEPTH"LV+1"-10%";:GOSUB9670:RETURN

5100 GOSUB570:I=INT(RND(1)*10)+5+LV
5101 IB=INT(RND(1)*2):B$="GOOD ":F$="":IFIB=1THENB$="EVIL ":F$=""
5102 SYSQ,28,2,""F$"":IFIB=1THENSYSQ,26,3,"  ":GOTO5104
5103 SYSQ,26,3,"  "
5104 SYSQ,25,4,""F$"  "F$" ":SYSQ,25,5,""F$"    "
5105 SYSQ,25,6,"   , ";
5106 PRINT"  ";
5107 GOSUB9610:IFCF=1ANDIB=1THEN5150
5108 IFCF=1THENI=I+I:SYSQ,1,21,"CF DOUBLES THE WISH POWER!";:GOSUB750
5110 GOSUB570:O=INT(I/10*100+.01):GOSUB26
5120 B%=14:SYSQ,0,20,B$"FAIRY:":IFIB=1THEN5130
5121 SYSQ,0,21,"WHAT WISH MAY I GRANT YOU?"
5123 SYSQ,1,22,"+"I"HEALTH":SYSQ,15,22,"+ "O$" BOOZY":SYSQ,29,22,"+"I"GOLD";:H=3:GOSUB700
5125 IFA%=1THENL=L+I
5126 IFA%=2THENPM=PM+(I/10):IFPM>3.5THENPM=3.5
5127 IFA%=3THENG=G+I
5128 SYSQ,1,24,"THE "B$"FAIRY FULFILLS YOUR DESIRE!";:GOTO5145

5130 SYSQ,0,21,"CHOOSE YOUR CURSE!"
5132 SYSQ,1,22,"-"I"HEALTH":SYSQ,15,22,"- "O$" BOOZY";:IFG-I<.THENH=2:GOTO5135
5133 SYSQ,29,22,"-"I"GOLD";:H=3
5135 GOSUB700:IFA%=1THENL=L-I
5136 IFA%=2ANDPM-(I/10)<.THENPRINT" YOU HAVE TOO LITTLE BOOZY!";:GOSUB750:GOSUB570:GOTO5120
5137 IFA%=2THENPM=PM-(I/10):IFPM<.THENPM=.
5138 IFA%=3THENG=G-I
5142 SYSQ,1,24,"THE "B$"FAIRY CRIES A CURSE! ";:IFL<.THENL=1
5145 GOSUB750:GOSUB570:K%(PX%,PY%)=1:RETURN

5150 SYSQ,28,4,"X X":SYSQ,1,21,W$(17)" SMACKS HER UP!":I=INT(RND(.)*5)+1
5152 SYSQ,1,22,"EVIL FAIRY DROPS "I"GOLD";:G=G+I:FK%=FK%+1:GOTO5145

5200 WK=INT(RND(1)*6)+1:WP=INT(RND(1)*6)+1:I=INT(RND(1)*4)+LV
5201 SYSQ,28,1," ";
5202 PRINT":  :";
5203 PRINT"1  1";
5204 PRINT"";
5205 PRINT"    ";:GOSUB9650
5206 GOSUB570:SYSQ,1,20,"GOBLIN: LET'S ROLL THE DICE!"
5207 SYSQ,1,21,"THY BET:  ALL-IN  "I"GOLD";:SYSQ,29,21,"NOTHIN'";
5208 B%=9:C%=10:H=3:GOSUB700
5210 IF(A%=1ANDG<1)OR(A%=2ANDG<I)THENSYSQ,1,22,"NOT ENOUGH SHINIES!":GOTO5250
5212 IFA%=3THENSYSQ,0,21,L$:GOTO5249
5214 IFA%=1THENU$=" ALL-IN":ZO%=ZO%+1
5216 IFA%=2THENU$=""+STR$(I)+" GOLD"
5220 SYSQ,10,21,U$LEFT$(L$,29-LEN(U$))
5221 FORX=.TO9:E$=RIGHT$(STR$(INT(RND(1)*6)+1),1)
5222 SYSQ,27,5,""E$""E$:TW=X*X/9:GOSUB20:GOSUB9670:NEXT
5224 SYSQ,27,5,""RIGHT$(STR$(WK),1)""RIGHT$(STR$(WP),1)
5226 SYSQ,1,22,"DICE RESULT: GOBLIN"WK" YOU"WP
5230 A$="YOU WIN":B$="YOU LOSE":C$="DRAW"
5231 IFA%=2GOTO5240
5232 IFWK<WPTHENSYSQ,1,23,A$G"GOLD";:G=G+G:GOTO5255
5234 IFWK>WPTHENSYSQ,1,23,B$G"GOLD";:G=0:GOTO5252
5236 IFWK=WPTHENSYSQ,1,23,C$;:GOTO5252
5240 IFWK<WPTHENSYSQ,1,23,A$I"GOLD";:G=G+I:GOTO5252
5242 IFWK>WPTHENSYSQ,1,23,B$I"GOLD";:G=G-I:GOTO5252
5244 IFWK=WPTHENSYSQ,1,23,C$;:GOTO5252
5249 SYSQ,1,22,"NO DICE."
5250 SYSQ,1,23,"GOBLIN SMACKS YOU! HEALTH -"I"%";:L=L-I:GOSUB9670
5252 GOSUB750:K%(PX%,PY%)=1:GOSUB570:A$="":RETURN

5255 POKE780,6:TW=60:GOSUB9270:IF(RND(1)*100)>1ORI%=4THEN5252
5258 SYSQ,1,24,"JACKPOT! "A$" "W$(20);:W(20,2)=1:I%=I%+1:D=5:GOTO5252

5300 K$="ORC":IB=INT(RND(1)*8):KW=23+N%:K%=9:BB%=RND(1)*6+1:IFVO%=1THEN5400:REM IB=4+5 CHAMP 6 HERO 7 ALKE
5301 IFVQ=1THENKW=KW+9:BB%=BB%+3:GOTO5305
5302 IF(IB>3ANDLV>2)THENK$="ORC CHAMP":KW=KW+6:BB%=BB%+2
5303 IF(IB>5ANDLV>3)THENK$="ORC HERO":KW=KW+15:BB%=BB%+5
5304 IF(IB>6ANDLV>4)THENK$="ORC CHIEF":KW=KW+20:BB%=BB%+5
5305 SYSQ,24,1,"  ";
5306 PRINT"   ";
5307 PRINT"    ";
5308 PRINT"   ";
5309 PRINT"       ";
5310 IFK$="ORC CHAMP"THENSYSQ,28,1," CHAMP ";
5311 IFK$="ORC HERO"THENSYSQ,28,1," HERO  ";
5312 IFK$="ORC CHIEF"THENSYSQ,28,1," ALKE1 ";
5314 POKE780,4:TW=60:GOSUB9270:GOSUB570
5320 GOSUB4400:IFA%=1THENGOSUB1600:GOSUB8570:GOTO5330
5325 GOSUB8580:GOSUB4410:GOSUB750:GOSUB680
5330 GOSUB9670:GOSUB9630:H=1:GOSUB570:RETURN

5400 K$="GUARD":KW=N%+10:K%=10:BB%=RND(1)*3+1
5401 SYSQ,25,1,"   ";
5402 PRINT"   ";
5403 PRINT"     STOP";
5404 PRINT"   ";
5405 PRINT"      ";:GOSUB9670
5410 GOSUB570:SYSQ,1,20,K$" STANDS IN THE WAY..."
5411 SYSQ,1,21,"DUEL OR  TOAST TO ORCISH BEER";:B%=9:H=2:GOSUB700
5416 IFA%=1THENGOSUB1600:GOSUB750:GOSUB8570:GOTO5428
5425 L=L+5:PM=PM+1:OS%=OS%+1:AB%=1:SYSQ,1,22,K$" GUARD DOZES OFF":SYSQ,29,2,"";
5427 SYSQ,1,23,"YOU GET 5% HEALTH AND 1.00 BOOZY";:GOSUB750:GOSUB8580
5428 GOSUB570:K%(PX%,PY%)=1:RETURN

5500 K$="GNOME":K%=11:W=G:BB%=INT(RND(1)*10)+1
5501 SYSQ,29,2," ";
5504 PRINT"    : :";
5507 PRINT" *";
5509 PRINT"";:POKECO+233,INT(RND(.)*15)+1:GOSUB9680
5510 GOSUB570:SYSQ,1,20,K$": EXCHANGE GOLD FOR HEALTH":W1%=100-L:IFW1%>GTHENW1%=G
5511 W2%=W1%/2:IFL=100THENW1%=G/2
5513 SYSQ,0,21,""W2%"GOLD":SYSQ,10,21,""W1%"GOLD":SYSQ,21,21,"FIGHT";:B%=10:H=3:GOSUB700:IFA%=1THENW1%=W2%
5514 IFA%=3THENGOSUB5540:KW=20+N%:GOSUB1600:K%(PX%,PY%)=1:GOSUB570:RETURN
5516 IFL<100ANDW1%>.THENL=L+W1%:SYSQ,0,22,""W1%"GOLD TRADED";:GOTO5520
5517 GOSUB680:IFW1%>.THENSYSQ,1,22,"YOU GIVE THE GNOME"W1%"GOLD";:GOTO5520
5518 SYSQ,1,22,"THE GNOME DISAPPEARS";
5520 G=G-W1%:GOSUB750
5530 K%(PX%,PY%)=1:GOSUB570:RETURN

5540 SYSQ,27,3,"      "
5542 U$="YOU LEAP INTO BATTLE!":RETURN

5600 K$="TROLL":KW=35+N%:K%=12:BB%=RND(1)*10+11:C$=CHR$(34)
5601 IFLV=5THENK$="ZOMBIE":KW=37+N%:K%=12:BB%=RND(1)*5+1:GOTO5620
5602 IFLV>5THENIB=INT(RND(1)*3):IFIB>1THENK$="ZOMBIE":KW=40+N%:BB%=RND(1)*5+5:GOTO5620
5605 SYSQ,24,1,"   ";
5606 PRINT"  ";
5608 PRINT"       ";
5610 PRINT":::: ";
5612 PRINT"   ";
5614 PRINT"";:GOSUB9670
5615 GOTO5630

5620 SYSQ,28,1,"-',";:PRINT""C$""C$""
5623 SYSQ,28,4,"  "
5627 SYSQ,28,8," ":GOSUB9670
5630 GOSUB570:GOSUB4400:IFA%=1THENGOSUB1600:GOTO5640
5635 GOSUB4410:GOSUB750:GOSUB680
5640 GOSUB570:RETURN

5700 BB%=RND(.)*3+8:K%=13:KW=INT((D%+3)*5+25):BB%=BB%+(D%+5)*2:C$=CHR$(34)
5702 F$=MID$("",D%+1,1):E$=MID$("",D%+1,1):K$=F$+"DRAGON"
5704 SYSQ,24,1,""E$" "F$"      "F$""E$" "
5706 SYSQ,24,2,"  "F$""E$"  "
5708 SYSQ,24,3,""E$" "F$""E$""F$"::"E$""F$""E$" "
5710 SYSQ,24,4,F$""E$"  "F$":"E$""F$":"E$"  "F$""
5712 SYSQ,24,5,""E$"  "F$")("F$""E$"  "
5714 SYSQ,24,6,""E$" "F$""E$" "F$""C$C$""F$""E$" "F$""E$" "
5716 SYSQ,24,7,F$""E$"  "F$""F$"."E$"  "F$""
5718 SYSQ,25,8,F$""E$""F$""E$""F$""
5720 SYSQ,26,9,E$""F$"::"F$":"E$""
5722 SYSQ,26,10,""F$" "F$"."F$" ":GOSUB9620:GOSUB9620
5724 GOSUB570:GOSUB4400:IFA%=1THENGOSUB1600:GOTO5730
5725 GOSUB4410:GOSUB750:GOSUB680
5730 GOSUB570:RETURN

5800 K$="FULGORE":K%=14:KW=100-D%*10:IFKW<30THENKW=30
5801 BB%=RND(1)*100+D%
5802 SYSQ,24,1,"*     ";
5804 PRINT"* ";
5805 PRINT"  ";
5806 PRINT"*      ";
5807 PRINT"  ";
5808 PRINT"";
5810 PRINT"     ";
5811 IFFB>.THENSYSQ,34,4,LEFT$("",FB+FB)
5812 GOSUB9620
5820 GOSUB570:GOSUB4400:IFA%=1THENGOSUB1600:GOSUB570:U=3:RETURN
5825 GOSUB4410:SYSQ,1,23,K$" ADVANCES TO DEPTH"LV+1;:GOSUB750:GOSUB200:RETURN

5880 GOSUB200:GOSUB570:IFS%=1THEN5900
5881 IFL<1THENSYSQ,2,21,"FULGORE STRUCK YOU DOWN...":V=3:GOSUB750:GOTO5950
5882 U=.:GOTO110

5900 POKE780,1:GOSUB9200:PRINT"        THE VICTORY IS YOURS!":PRINT" YOU BESTED FULGORE!";
5901 IFD%>.THENPRINT" AND"D%"OF HIS"CHR$(13)" FIERCE DRAGONS!";
5903 PRINT" SLEDGIE IS FREE"
5904 PRINT" TO PLUNGE INTO HIS NEXT ADVENTURE..."
5907 PRINT"                                  ";
5908 PRINT"             ";
5909 PRINT"   ";
5910 PRINT"               ";
5911 PRINT"                     ";
5912 PRINT"                         ";
5913 PRINT"                       ";
5914 PRINT"                           ";
5915 PRINT"                       ";
5916 PRINT"                        ";
5917 PRINT"                          ";
5918 PRINT"              ";
5919 PRINT"      :            ";
5920 PRINT"    :  :       ";
5922 PRINT"     ,      ";
5923 PRINT"%     ";
5924 PRINT"      ";
5925 PRINT"                  ";
5926 PRINT"  ";
5929 V=3:GOSUB750:G$="FULGORE HAS BEEN DEFEATED!":GOTO7000

5950 POKE780,2:GOSUB9200:GOSUB6000
5955 V=3:GOSUB750:G$="FULGORE HAS BEATEN YOU!":GOTO7000

6000 PRINT"     YOUR EFFORTS WERE NOT ENOUGH!"
6002 PRINT"         YOU FAILED, LIKE MANY"
6004 PRINT"       OTHER DWARVES BEFORE YOU."
6006 PRINT"  SLEDGIE REMAINS FULGORE'S PRISONER."
6008 PRINT"                ";
6010 PRINT"              ";
6012 PRINT"   :     ";
6014 PRINT"      :         ";
6016 PRINT"        '        :     ";
6018 PRINT"      :       '    ";
6020 PRINT"      :                ";
6022 PRINT"     :     &&          ";
6024 PRINT"      :     &&      ";
6026 PRINT"         &&           ";
6028 PRINT"                  ";
6030 PRINT"                    ";
6032 PRINT"         '            ";
6034 PRINT"                     ";
6036 PRINT"           ,%        ";
6038 PRINT"                 ";
6040 PRINT"       ";
6042 PRINT"              "
6044 RETURN

6200 I=UT:IFUT<.THENI=INT(RND(1)*7):REM DRAKRI PER ZUFALL
6202 K$="DRAKRI":KW=(90-I*7)+N%:K%=15:BB%=KW-RND(1)*7:UT=UT-1
6205 C$=MID$("",D%+1,1):IFI<3THEN6225
6220 SYSQ,29,1,"   &";:REM DRAKRI SCHWERT
6222 PRINT"  & &";
6224 PRINT" ";:GOTO6230

6225 SYSQ,28,1,"";:REM DRAKRI HELM AXT
6226 PRINT" ";
6228 PRINT" ";
6230 SYSQ,26,6,"     ";:PRINT""C$">"
6231 SYSQ,26,9,"  ":GOSUB9670
6240 GOSUB570:GOSUB4400:IFA%=1THENGOSUB1600:GOTO6250
6245 GOSUB4410:GOSUB750:GOSUB680
6250 GOSUB570:RETURN

7000 POKE780,2:GOSUB9200:IFA%<0THENGOSUB6000:A%=0:V=3:GOSUB750
7001 PRINT"";:PRINTSPC(19-LEN(G$)/2)G$:C%=30
7002 SYSQ,1,2,"   YOUR QUEST ENDED AT DEPTH"LV"  "
7004 A%=(D%*D%+D%)/2*100:B%=S%*2000:E=1000:IFLV>6THENIFLV<12THENE=(12-LV)*1000
7006 PRINT"      ADVENTURE POINTS"TAB(C%-LEN(STR$(PU)))PU
7010 PRINT""TAB(17-LEN(STR$(G)))G"GOLD +"TAB(C%-LEN(STR$(G+G)))G+G
7012 PRINTTAB(7)""D%"OF 7 DRAGONS +"TAB(C%-LEN(STR$(A%)))A%
7014 PRINTTAB(7-LEN(STR$(GA%)))""GA%"OF 12 MISSIONS +";:GA%=GA%*250:PRINTTAB(C%-LEN(STR$(GA%)))GA%
7020 IFS%=0THENE=0:GOTO7040
7025 PRINT"         FULGORE SLAIN +"TAB(C%-LEN(STR$(B%)))B%
7030 PRINTTAB(14-LEN(STR$(LV)))"IN DEPTH"LV"+"TAB(C%-LEN(STR$(E)))E
7040 PRINTTAB(25)"":PU=PU+G+G+A%+B%+E+GA%:PRINT"          TOTAL POINTS"TAB(C%-LEN(STR$(PU)))PU""
7050 GOSUB900:POKE214,15:PRINT:GOSUB7100:V=3:GOSUB750:GOSUB9250:GOTO30

7100 PRINT"DWARF HERO   SCORE TRIUMPHS & RANK":FORII=0TO4
7102 PRINT""N$(II)TAB(18-LEN(STR$(P(II))))""P(II)TAB(19)R$(II):NEXT:RETURN

7110 PRINT"IDEA & DESIGN SLEDGIE":PRINT"CODING SLEDGIE, RETROLYNX, 1570"
7113 PRINT"GRAPHICS SLEDGIE, RETROLYNX, DAIMANSION":PRINT"MUSIC & SFX RICHARD BAYLISS, RETROLYNX"
7115 PRINT"ENGLISH TRANSLATION JAMMET, RETROLYNX":RETURN

7120 PRINT"   FULGORE, THE ORC SHAMAN, KEEPS":PRINT"   SLEDGIE LOCKED IN HIS DUNGEON,"
7122 PRINT"   GUARDED BY 7 LOYAL DRAGONS.":PRINT"   DESCEND BOLDLY. DEFEAT FULGORE"
7125 PRINT"   AND HIS MINIONS. FREE SLEDGIE!":RETURN

7200 IFAB%=.ANDLV>3THENA$="ABSTAINER":AB%=-1:GOSUB197:GOTO7202:REM EXIT
7201 IFAB%=1THENAB%=.
7202 POKE780,3:TW=60:GOSUB9270
7204 PRINT"";:PRINT"YOU SURVIVED DEPTH"LV"!"
7208 A%=LV*100:IFLV>5THENA%=500
7210 A%=A%+L:PRINT" BONUS POINTS     +"TAB(23-LEN(STR$(A%)))A%
7215 PU=PU+A%:PRINT" ADVENTURE POINTS"TAB(23-LEN(STR$(PU)))PU""
7216 GOSUB8300:PRINTCHR$(13)"YOUR BACKPACK CONTAINS":Z=.
7218 FORII=13TO25:IFW(II,2)=1THENPRINT" "W$(II):Z=Z+1
7219 NEXT:IFZ=.THENPRINT" NOTHING"
7229 PRINT""N$", YOU HAVE THE CHOICE:"
7230 PRINT" VISIT TAVERN         JOURNEY ON";:H=2:B%=21:GOSUB700
7235 IFA%=2THENES%=ES%+1
7240 IFA%=1THENGOSUB8000:H%=0:REM GO TAVERN
7300 LV=LV+1:AE=0:CF=0:WD=0:TS=0:SW=0:GOSUB7800:A%=FRE(0):GOTO100

7800 PRINT:PRINT"DOWN WE GO TO DEPTH"LV"";
7805 TI$="000000":IFU=1THENSYSQ,1,22,"YOU FALL AND LOSE GOLD.";:G=INT(G*.8)
7810 PRINT".";:GOSUB1000:PRINT".";
7860 BI=INT(RND(.)+0.8*LV):IFLV<2THENBI=LV
7862 FA=INT(RND(.)+0.7*LV)
7863 ES=INT(RND(.)+0.6*LV):IFLV<2THENES=LV
7864 FE=INT(RND(.)+0.5*LV)
7865 KO=INT(RND(.)+0.4*LV)
7866 OK=LV
7867 WE=INT(RND(.)+0.5*LV)
7868 WI=INT(RND(.)+0.6*LV):IFLV<3THENWI=LV-1
7869 TR=INT(RND(.)+0.7*LV)-1
7870 IFLV=5THENTR=10:REM ZOMBIE-LEVEL
7875 GN=1:IFLV>3THENGN=2
7876 IFLV>4THENKK%=15:GOSUB670:REM DRAKRI
7878 KK%=3:FORII=1TOGN:GOSUB670:NEXT
7879 IFLV>14THENBI=12:FA=10:ES=9:FE=7:KO=6:OK=15:WE=7:WI=9:TR=9
7880 IFBI>0THENKK%=4:FORII=1TOBI:GOSUB670:NEXT
7881 IFFA>0THENKK%=5:FORII=1TOFA:GOSUB670:NEXT
7882 IFES>0THENKK%=6:FORII=1TOES:GOSUB670:NEXT
7883 IFFE>0THENKK%=7:FORII=1TOFE:GOSUB670:NEXT
7884 PRINT".";:IFOK>0THENKK%=9:FORII=1TOOK:GOSUB670:NEXT
7885 IFKO>0THENKK%=8:FORII=1TOKO:GOSUB670:NEXT
7886 IFWI>0THENKK%=11:FORII=1TOWI:GOSUB670:NEXT
7887 IFWE>0THENKK%=10:FORII=1TOWE:GOSUB670:NEXT
7888 IFTR>0THENKK%=12:FORII=1TOTR:GOSUB670:NEXT
7889 IFLV>2THENIFD%<7THENKK%=13:GOSUB670
7890 IFLV>4THENKK%=14:GOSUB670:REM 5->3 FULGI 2.0
7891 IFLV=3THENIFNQ=1THENFORII=16TO18:KK%=II:GOSUB670:NEXT
7892 PRINT".";:IFLV=4THENIFNQ=1THENFORII=19TO21:KK%=II:GOSUB670:NEXT:REM 18 TO 20
7893 IFTI<300THEN7893
7897 K$(13)=MID$("",D%+1,1)+">":RETURN

7900 ZO=ZO+1:IFG<1THENSYSQ,1,11,"OUT OF GOLD";:GOSUB750:RETURN
7902 A%=3:IFG>50THENA%=2:IFG>99THENA%=1
7905 IFZO>A%THENSYSQ,1,11,"NOBODY WANTS TO PLAY";:GOSUB750:RETURN
7910 SYSQ,2,12,"    DWARVEN POKER    "
7912 PRINT"YOUR CARD      ";:GOSUB7960
7926 XS=X:YS=Y:PRINT"  >BET    GOLD";:H=G:IFH>99THENH=99
7928 V=2:GOSUB700:SYSQ,0,17,"SHMENDRIC HAS  ";:GOSUB7960
7945 IFYS>YTHENSYSQ,1,20,"YOU WIN"A%"GOLD";:G=G+A%:REM POKE780,6:TW=60:GOSUB9270
7950 IFYS<YTHENSYSQ,1,20,"YOU LOSE"A%"GOLD";:G=G-A%
7955 IFYS=YTHENSYSQ,1,20,"IT'S A DRAW";
7956 D=4:GOSUB750:RETURN

7960 X=INT(RND(1)*4):Y=INT(RND(1)*13):IFX=XSTHENIFY=YSTHEN7960
7962 PRINTMID$("",X+X+1,2)MID$("2 3 4 5 6 7 8 9 10B D K A ",Y+Y+1,2);
7964 RETURN

7970 IB=1:IFH%=1THEN7974
7971 R%=LV-1
7972 IFLV>4THENR%=RND(1)*4:IFR%=VH%THEN7972
7973 K$=MID$("TELELYNXJAMMETPAT",R%*8+1,8):PS=R%/5+.6:VH%=R%
7974 SYSQ,2,8,""
7975 PRINT"         :"
7976 PRINT"    '         :"
7977 PRINT"      '           "
7978 PRINT"                 "
7981 PRINT"           $$"
7983 PRINT"           $$ "
7985 PRINT"   ;"
7987 PRINT"  ;;"
7988 PRINT" "K$" OFFERS HIS FINE GOODS:"LEFT$(K$,1);
7990 SYSQ,14,9," ";
7991 PRINTRIGHT$(K$,1);:PRINT" "
7992 SYSQ,1,20,"JUST BROWSING...":GOSUB4211:GOTO8020

8000 KA=0:ZO=0:H%=2:C$=A$(INT(RND(1)*12))+" "+B$(INT(RND(1)*12))
8001 Y=LEN(C$)+6:X=17-INT(Y/2):A$=""
8005 PRINT"";:SYSQ,13,0,"":F=INT(RND(1)*3)+26
8006 SYSQ,X,1,""LEFT$(A$,Y-2)"":PRINT""SPC(13)"TAVERN"
8007 SYSQ,X,2,"THE "C$"":SYSQ,X,3,""LEFT$(A$,Y-2)"":A$=""
8010 IFLV=2THENGOSUB8200:X=5:GOSUB8198
8012 IFLV=4THENIFNQ=1THENGOSUB8240:X=5:GOSUB8198
8014 IFFB>.ANDL1=.THENGOSUB8400:X=5:GOSUB8198
8016 IFL1=LVTHENGOSUB8500:X=5:GOSUB8198
8020 X=8:GOSUB8198:SYSQ,0,5,L$;:SYSQ,0,5,"YOUR STATUS:"
8025 GOSUB8300:PRINT"BACKPACK";:PRINTI%"/4"
8026 SYSQ,0,8,""N$", YOU WOULD LIKE TO..."
8030 H=2:IFH%>0THENSYSQ,1,10,"VISIT THE MERCHANT":H=3
8031 IFH%<1THENSYSQ,1,15,"THE SHOP IS CLOSED"
8032 SYSQ,1,11,"PLAY DWARVEN POKER"
8034 SYSQ,1,12,"SIT AT A TABLE AND HAVE A MEAL";:V=1:GOSUB700
8050 X=8:GOSUB8198:X=0:IFH%>0THENX=1:IFA%=1THEN7970
8054 IFA%=1+XTHENGOSUB7900:GOTO8020
8080 B$=" WHY'S THERE NEVER ENOUGH GOLD?":C$=" SERVE ME SOMETHING ELSE"
8090 X=10:GOSUB8198:SYSQ,0,8,"WHAT WILL IT BE?"
8092 SYSQ,1,10,"MEALS   DRINKS  MENUS   LEAVE TAVERN";
8096 H=4:B%=8:GOSUB700:X=10:GOSUB8198:ONA%GOTO8120,8140,8160,8199:REM 7290
8120 SYSQ,4,10," HEARTY MEALS "
8121 PRINT" TROLL STEW          +15%    -"INT(.15*LV)
8122 PRINT" FRIED PIXIE WINGS   +25%    -"INT(.5*LV)
8123 PRINT" ORCEN MUTTON LEG    +35%    -"INT(1.5*LV)
8124 PRINTC$;:V=1:H=4:GOSUB700:IFA%=4THEN8090
8130 IFA%=1THENK%=.15*LV
8131 IFA%=2THENK%=.5*LV
8132 IFA%=3THENK%=1.5*LV
8133 IFK%>GTHENPRINTB$;:GOSUB750:GOTO8090
8134 G=G-K%:L=L+5+A%*10:REM IFA%=2THENG=G-K%:L=L+25
8137 GOTO8190

8140 SYSQ,4,10," FINEST DRINKS "
8141 PRINT" SNAKE WINE"TAB(19)"+ 5% +1.5 -"INT(.25*LV)
8142 PRINT" SWEET FAIRY JUICE"TAB(19)"+20% +0.2 -"LV
8143 PRINT" "LEFT$(W$(F),12)TAB(19)RIGHT$(W$(F),11)" -"2*LV
8144 PRINTC$;:V=1:H=4:GOSUB700:IFA%=4THEN8090
8150 IFA%=1THENK%=.25*LV
8151 IFA%=2THENK%=LV
8152 IFA%=3THENK%=LV+LV
8153 IFK%>GTHENPRINTB$;:GOSUB750:GOTO8090
8154 G=G-K%:IFA%=1THENL=L+5:PM=PM+1.5
8155 IFA%=2THENL=L+20:PM=PM+0.2
8156 IFA%=3THENL=L+W(F,0):PM=PM+W(F,1)
8157 GOTO8190

8160 SYSQ,4,10," TASTY MENUS "
8161 SYSQ,4,11,"(100% HEALTH IN EVERY MEAL)"
8163 PRINT" STANDARD MOLE RAGOUT   +2.5 -";:PRINT2*LV
8164 PRINT" DELUXE   UNICORN ROAST +3.0 -";:PRINT4*LV
8165 PRINT" MAXI     DRAGON BREAST +3.5 -";:PRINT8*LV
8166 PRINTC$;:V=1:H=4:GOSUB700:IFA%=4THEN8090
8170 IFA%=1THENK%=2*LV
8171 IFA%=2THENK%=4*LV
8172 IFA%=3THENK%=8*LV:GT%=GT%+1
8173 IFK%>GTHENPRINTB$;:GOSUB750:GOTO8090
8174 G=G-K%:L=100:IFA%=1THENPM=2.5
8175 IFA%=2THENPM=3
8176 IFA%=3THENPM=3.5
8190 IFK%=0THENPRINT"YOU ARE LUCKY TO GET A FREE MEAL":GOTO8192
8191 PRINT"YOU TOSS"K%"GOLD TO THE INNKEEPER"
8192 PRINT"AND YOU EAT LIKE A HORSE."
8193 IFG<0THENG=0
8194 IFL>100THENL=100
8195 IFPM<.THENPM=.
8196 K%=0:GOSUB8300:PRINT:RETURN:REM TO7240

8198 FORII=XTO24:SYSQ,0,II,"                                       ";:NEXT:RETURN

8199 POKE214,6:PRINT:RETURN:REM TO7240

8200 PRINT"A SEEDY GNOME WAVES YOU OVER TO JOIN"
8204 PRINT"HIM AT HIS TABLE IN A DARK CORNER."
8206 PRINT"GNOME:":PRINT" LISTEN UP! THERE BE SIX MAGIC RUNES"
8207 PRINT" HIDDEN IN FULGORE'S STINKY DUNGEON."
8208 PRINT" GO FIND THEM AND TELL ME THE RUNE"
8209 PRINT" WORD WHEN WE MEET AGAIN."
8210 PRINT" I WILL REWARD YOU APPROPRIATELY."
8213 PRINT"DO YOU ACCEPT THIS QUEST?  SURE  NOPE";:H=2:B%=6:C%=26:GOSUB700
8214 IFA%=1THEN8220
8215 PRINT" BAD LUCK! THOUGHT YOU WERE BRAVER.  "
8216 PRINT"THE GNOME BURPS IN YOUR FACE AND"
8217 PRINT"BUMPS INTO YOU ON HIS WAY OUT."
8218 PRINT"LITTLE LATER YOU NOTICE THAT SOME":PRINT"OF YOUR GOLD IS MISSING."
8219 PRINT"CURSES!":G=INT((G+1)/2):V=3:GOSUB750:RETURN

8220 PRINT" VERY WELL, I'LL WAIT FOR YOU IN THE "
8222 PRINT" TAVERN AT THE END OF DEPTH 4."
8230 V=3:GOSUB750:NQ=1
8232 FORA=0TO2:Q$=Q$+MID$("ASINUROGEMODENAM",INT(RND(1)*15)+1,2):NEXT:RETURN

8240 PRINT"YOU SEE THE GNOME SITTING AT THE BAR.":NQ=0
8250 PRINT"GNOME:":PRINT" FRIEND! YOU MADE IT BACK! "
8252 PRINT" HAVE YOU FOUND ALL THE RUNES?"
8254 PRINT" YES!  WHAT RUNES?";:H=2:B%=6:GOSUB700:IFA%=1THEN8264
8256 PRINT" STUPID FOOL WASTED MY TIME!":GOTO8216

8264 PRINT" EXCELLENT!       ":PRINT" TELL ME THE RUNE WORD: ";:A%=0:GOSUB800
8270 IFG$<>Q$THENPRINT:PRINT" IT'S FALSE! IT HOLDS NO MAGIC!":GOTO8216
8272 PRINT:PRINT" YES! IT WORKS! I FEEL MAGIC POWER!":NQ=2
8276 PRINT"THE GNOME DROPS 100 GOLD & 500 POINTS":G=G+100:PU=PU+500
8277 V=3:GOSUB750:RETURN

8300 PRINT"HEALTH"L"%"TAB(13)"BOOZY ";:GOSUB25:PRINTO$"   GOLD"G"  ";:RETURN

8400 PRINT"A DESPERATELY GESTURING DWARF":PRINT"STEPS CLOSE."
8402 PRINT"DWARF:":PRINT" FULGORE PUT A CURSE ON ME WIFE!"
8403 PRINT" SHE NOW LOOKS LIKE AN ORC, WANDERING"
8404 PRINT" THESE MINES ALL ALONE! SHOULD SHE"
8405 PRINT" ATTACK, I BEG YE TO SPARE HER LIFE.":
8406 PRINT" PLEASE FIND HER! MY GRATITUDE WOULD":PRINT" BE BOUNDLESS!"
8407 W=INT(30+(G/10)):IFW>100THENW=99
8408 PRINT" I CAN OFFER YOU MY MAGIC MAP FOR":PRINTW"GOLD. DO YOU WANT IT?"
8409 PRINT" YES  NO";:H=2:B%=5:GOSUB700:PRINT"         "
8410 IFA%=2THENPRINT" INDEED A DARING DWARF!":GOTO8420
8411 IFG<WTHENPRINT"YOU DON'T HAVE ENOUGH GOLD!":GOTO8420
8412 IFI%=4THENPRINT"YOUR BACKPACK IS ALREADY FULL!":GOTO8420
8413 IFW(13,2)=0THENB$=W$(13):W(13,2)=1:I%=I%+1:A%=1:G=G-W:GOTO8415
8414 PRINT"YOU ALREADY OWN A MAGIC MAP!":GOTO8420

8415 PRINT" TAKE MY MAGIC MAP, GOOD LUCK!"
8420 PRINT"YOU SWEAR NOT TO HARM ANY ORCS"
8421 PRINT"UNTIL YOU'VE FOUND HIS POOR WIFE":PRINT"AMONG THEM."
8422 VO%=RND(1)*4+5:L1=LV+1:VQ=1:V=3:GOSUB750:RETURN

8500 L1=-1:PRINT"YOU SEE THAT DESPERATE DWARF"
8501 IFVO%<0THEN8550
8502 IFVO%>0THEN8560
8503 PRINT"AND DELIVER THE GOOD NEWS.":PRINT"DWARF:"
8504 PRINT" YE FOUND ME WIFE!? ":PRINT" SHE'S ALLRIGHT AND LOOKS"
8505 PRINT" LIKE AN ORC GUARD, YE SAY?":PRINT" AN' YE HAD A DRINKIN' DUEL?!"
8508 PRINT" SOUNDS EXACTLY LIKE HER...":PRINT" I'LL CURE HER WITH DAIMANSION'S"
8510 PRINT" MAGIC TRANSFORMATION POTION!":PRINT" MY GRATITUDE IS IMMEASURABLE!"
8511 PRINT"THE DWARF HURRIES TOWARDS THE":PRINT"SNORING NOISE NEARBY."
8513 PRINT"YOU GAIN 1000 POINTS AND":PU=PU+1000:VQ=2:FB=2
8514 PRINT"WEAKENED FULGORE TO BOOT.":GOTO8553

8550 PRINT"AND HIDE AWAY WITH SHAME."
8551 PRINT"YOU HAVE KILLED HIS WIFE!"
8552 PRINT"THERE IS BLOOD ON YOUR HANDS."
8553 VO%=0:V=3:GOSUB750:RETURN

8560 PRINT"AND CONFESS YOUR FAILURE."
8561 PRINT"DWARF:":PRINT" YE HEART ISN'T IN IT AT ALL!"
8562 PRINT" I HAD ALL ME HOPES PUT IN YE.":PRINT" ...ALL FOR NAUGHT!"
8563 PRINT"THE DWARF SETTLES DOWN ON A"
8564 PRINT"CHAIR, HOPING FOR ANOTHER HERO."
8565 GOTO8553

8570 IFVQ<>1THENVO%=0:RETURN
8571 IFJG<>.THENRETURN
8572 IFVO%>0ANDF=1THENVO%=-1:GOSUB220:GOSUB570:SYSQ,1,21,"FULGORE'S SPELL VANISHES. IN FRONT OF":PRINT" YOU LIES THE LIFELESS DWARF WIFE...";:D=6:GOSUB750
8573 RETURN

8580 IFVQ<>1ORVO%=0THENVO%=0:RETURN
8581 IFVO%>1THEN8586
8582 IFVO%<0THENRETURN
8583 GOSUB570:SYSQ,1,21,"THIS 'ORC' WEARS A WEDDING RING. ";
8584 FORE=0TO2:FORD=0TO242:POKE646,D:PRINT"";:NEXT:NEXT
8585 SYSQ,1,22,"YOU HAVE FOUND THE DWARF'S WIFE!";:D=8:GOSUB750
8586 VO%=VO%-1:REM IFJG<>.ANDK%=10THENVO%=VO%+1
8587 RETURN

9000 POKE780,.:GOSUB9200:POKE198,.
9001 PRINT"";:SYSQ,7,0," "
9002 PRINT"      EXTENDED"
9003 PRINT"       EDITION"
9004 PRINT"      "
9005 PRINT"        "
9006 PRINT"         "
9007 PRINT"       "
9008 PRINT"     "
9009 PRINT"        "
9010 PRINT"      "
9011 PRINT"        "
9012 PRINT"           "
9013 PRINT"    HEX OF THE 7 DRAGONS  "
9014 PRINT"     "
9016 SYSQ,12,23,"STRIKE A KEY"
9017 SYSQ,6,24,"AND LET YOUR QUEST BEGIN!";:A%=0
9020 SYSQ,0,14,"":JJ=640:A%=A%+1:IFA%>3THENA%=1
9021 FORII=0TO6:PRINT"                                       ":NEXT
9022 TI$="000000":TW=TI:SYSQ,0,14,"":ONA%GOSUB7100,7120,7110
9023 GETT$:J=PEEK(56320)AND127:IFJ=111ORT$<>""THEN9030
9024 IFA%=2ANDJJ<880THENPOKECO+JJ,1:JJ=JJ+1:TW=1:GOSUB20:TI$="000002":GOTO9023
9025 IFTI<300THEN9023
9026 GOTO9020

9030 IFT$=""THENIFID>3THENGOSUB9260:OPEN1,ID,15,"S:FAME":CLOSE1:GOSUB9330:GOTO9001
9031 IFT$="8"ORT$="9"THENPOKE186,VAL(T$):GOSUB9300:GOTO9001
9034 IFT$="F"THENGOSUB9070:GOTO9025
9035 REM IFT$="S"THENGOSUB9250:GOSUB9600:GOSUB9200
9038 RETURN

9050 F=0:IFPEEK(52992)=76THENF=1:REM IF MUSIC HELPER IS PRESENT, ASSUME CHARSETS ARE, TOO
9051 RETURN

9060 GOSUB9050:IFF=0THENPRINTCHR$(142);:RETURN
9061 SC=50217:POKE56576,148:IFPEEK(648)<>196THENPRINTCHR$(14);:POKE53272,20
9062 POKE648,196:RETURN

9070 GOSUB9050:IFF=0THENRETURN
9071 IF(PEEK(53272)AND14)=4THENPOKE53272,22:RETURN
9072 POKE53272,20:RETURN

9100 DIML$,A$(14),B$(14),K$(21),W$(28),M%(12),W(28,2),K%(15,15),FS%(127,1)
9101 DIMC$(3),N$(4),P(4),R$(4)
9102 C$(0)="":C$(1)="":C$(2)="":C$(3)=""
9106 Q=830:FORII=QTOQ+42:READB%:POKEII,B%:NEXT:REM DISTREMOVE
9107 DATA173,225,244,201,201,240,14,32,155,183,134,211,32,155,183::REM DISTREMOVE
9108 DATA32,140,232,76,19,171,32,121,0,32,155,231,134,211,32,121:REM DISTREMOVE
9109 DATA0,32,155,231,134,214,32,121,0,76,8,245:REM DISTREMOVE
9110 FORII=0TO14:READA$(II),B$(II):NEXT
9112 DATAFIERY,DRAGON,SLAUGHTERED,LAMB,JOLLY,HALFLING
9114 DATAGOLDEN,LION,DYING,SWAN,BLESSED,WHALE,OLDE,GNOME
9116 DATABLOODY,LONGBEARD,BRAVE,DWARF,LARGE,ORC,WISE,SHAMAN
9118 DATASPICED,BOAR,HEARTY,OX,SINGING,BARD,DEAF,TROLL
9130 FORII=0TO21:READK$(II):NEXT:L$="                                       "
9132 DATA" "," ","<","","*","*","*","@","@","@","@"
9134 DATA"@","@",">","@","@","1","2","3","4","5","6"
9140 FORII=1TO28:READW$(II):NEXT
9142 DATA"DAGGER +3       ","SPEAR +4        ","SWORD +5        ":REM 1-12
9144 DATA"HATCHET +6      ","NUNCHAKU +7     ","MAUL +8         "
9146 DATA"AXE +10         ","MORNING STAR +12","WAR HAMMER +14  "
9148 DATA"BATTLE AXE +16  ","RUNIC HAMMER +18","GORKONS AXE +20 "
9160 DATA"LYNX'S MAGIC MAP","ADTBM POTION","PAT'S DOUBLE STRIKER":REM 13-20
9162 DATA"SHMENDRIC'S AMULET","CAMI'S FAIRY SWATTER","JAMMET'S GEMS"
9164 DATA"TARGA'S MAGIC SHIELD","THY HOLY HANDGRENADE"
9170 DATA"DWARVEN GIN +50% +0.5","IMP ALE     +20% +0.2":REM TRANK21-28
9172 DATA"ELVEN WINE  +10% +0.4","ORCEN BEER  + 5% +1.0"
9173 DATA"HOBBIT BEER +30% +0.4","DRAGON WINE + 5% +2.0"
9174 DATA"1570TH BREW +40% +1.7","TROLL RUM   +25% +2.5"
9190 FORII=1TO28:READW(II,.):READW(II,1):W(II,2)=.:NEXT:RETURN

9192 DATA3,,4,4,5,7,6,11,7,16,8,22,10,30,12,40,14,60,16,100,18,150,20,210:REM WEAPONS
9194 DATA0,10,,7,,20,,15,,4,,2,,6,,270:REM ITEMS
9196 DATA50,.5,20,.2,10,.4,5,1,30,.4,5,2,40,1.7,25,2.5:REM DRINKS
9200 IFPEEK(52992)=76THENIFPEEK(789)<>207THENSYS52992:REM START MUSIC
9201 RETURN

9250 IFPEEK(789)=207THENSYS52995:RETURN:REM STOP MUSIC, INITS SID FOR SFX
9251 IFPEEK(52992)<>76THENGOSUB9800:REM NO MUSIC HELPER, INIT SID FOR SFX, DISTREMOVE
9252 RETURN

9260 IFPEEK(789)<>207THENRETURN:REM PAUSE MUSIC
9261 IFPEEK(1020)<>52THENPOKE1020,52:POKESI+24,0:RETURN
9262 POKE1020,0:POKESI+24,15:RETURN

9270 GOSUB9200:GOSUB20:GOSUB9250:RETURN

9290 ID=PEEK(186):OPEN1,ID,15:CLOSE1:IFSTTHENID=0
9291 RETURN

9300 GOSUB9290:IFID<4THEN9330
9305 GOSUB9260:OPEN1,ID,15,"R:FAME=FAME":INPUT#1,A%:CLOSE1
9306 IFA%<>63THEN9330
9310 OPEN1,ID,2,"FAME,S,R":FORB=0TO4:INPUT#1,N$(B),P(B),R$(B):NEXT:CLOSE1
9311 GOSUB9260:RETURN

9320 GOSUB9290:IFID>3THENGOSUB9260:OPEN1,ID,15,"S:FAME":CLOSE1
9325 IFID<4THENRETURN:REM DEVICE IS TAPE OR NOT READY = NO SAVE
9326 OPEN1,ID,2,"FAME,S,W":FORB=0TO4:PRINT#1,N$(B)","P(B)","R$(B):NEXT:CLOSE1
9327 OPEN1,ID,15,"UI":CLOSE1:RETURN:REM DRIVE RESET

9328 GOSUB9260:RETURN

9330 N$(0)="ALRIK":N$(1)="BORIM":N$(2)="CADRIX":N$(3)="DURGIN":N$(4)="ENLAG"
9331 PU=6000:FORB=0TO4:P(B)=PU:GOSUB930
9332 R$(B)=" ..... "+R$:PU=INT(PU/2):NEXT:PU=.:GOSUB9290:GOTO9325

9600 REM PRINT"1-8 9=FX":GETA$:IFA$=""THEN9600
9602 REM IFA$=" "THENRETURN
9604 REM Z=VAL(A$):POKE646,Z:PRINTA$;:REM PK%=168:KW%=99:K$="ORKUS":GOSUB570
9606 REM ONZGOSUB9610,9620,9630,9640,9650,9660,9670,9680,9690:GOTO9600
9610 POKESI+11,33:TW=8:GOSUB20:POKESI+11,32:RETURN:REM BELL

9620 POKESI+11,129:TW=14:GOSUB20:POKESI+11,128:RETURN:REM SPLASH

9630 POKESI+4,129:TW=4:GOSUB20:POKESI+4,128:RETURN:REM STEP

9640 POKESI+11,17:TW=8:GOSUB20:POKESI+11,16:RETURN:REM PLING

9650 POKESI+18,33:TW=8:GOSUB20:POKESI+18,32:RETURN:REM BEEP

9660 POKESI+4,65:TW=8:GOSUB20:POKESI+4,64:RETURN:REM TSCHING

9670 POKESI+18,129:TW=3:GOSUB20:POKESI+18,128:RETURN:REM HIT

9680 POKESI+18,17:TW=8:GOSUB20:POKESI+18,16:RETURN:REM BLIP

9690 SYSQ,1,20,"YOU FIGHT LIKE ";:A$="A COW!":IFPM>.5THENA$="A LAME DUCK!"
9691 IFPM>1THENA$="A DRUNKEN MONKEY!"
9692 IFPM>1.5THENA$="A NIMBLE WEASEL!"
9693 IFPM>2THENA$="A BRAVE LION!"
9694 IFPM>2.5THENA$="A DEADLY SNAKE!"
9695 IFPM>3THENA$="A FIERY DRAGON!"
9696 PRINTA$;
9698 POKESI+1,70:POKESI+6,2*16+9:A%=KW%/8:IFPK%>KW%THENA%=PK%/8
9699 FORX=.TO8:Z%=RND(.)*6:IFZ%=.THENPOKESI+4,65
9700 SYSQ,1,23,K$""TAB(11);:I=INT(A%*X+RND(.)*A%):IFI>KW%THENI=KW%
9702 GOSUB9720:SYSQ,1,22,"STRENGTH  ";:I=INT(A%*X+RND(.)*A%):IFI>PK%THENI=PK%
9706 GOSUB9720:POKESI+18,129:TW=5:GOSUB20:POKESI+4,64:POKESI+18,128
9715 TW=RND(.)*17+5:GOSUB20:POKESI+15,RND(.)*100+90:NEXT
9716 POKESI+15,26:POKESI+1,11:POKESI+6,2*16+2:RETURN

9720 C%=I/8:PRINTLEFT$(""+L$,C%+1);
9725 B%=I-C%*8:PRINTMID$(" ",B%+B%+1,2)""I"   ";:RETURN

9800 RESTORE:FORII=0TO23:POKESI+II,0:NEXT:POKESI+24,15:REM DISTREMOVE
9805 I=0:POKESI+3,7:POKESI+2,7:FORX=1TO3:READFH,FL,AN,AS,HA,AU:REM DISTREMOVE
9810 POKESI+6+I,HA*16+AU:POKESI+5+I,AN*16+AS:POKESI+1+I,FH:POKESI+I,FL:REM DISTREMOVE
9815 I=I+7:NEXT:HA=0:RETURN:REM DISTREMOVE

9900 IFS<0THENS=0
9910 IFS>LTHENIFS-L<10THENS=L-INT(RND(1)*10)+3
9920 IFL-S<1THENS=L
9930 RETURN